Syntax

FETCH    ::= 'FETCH' entityName '(' property ( ',' property )* ')' linkedEntities* ( 'FILTER' filter )? orderBy? ( 'LIMIT' int ( ',' int )? )?

property ::= ( propertyName ( 'AS' alias )? | ( 'SUM' | 'AVG' | 'STD' | 'MIN' | 'MAX' | 'COUNT' | 'CONCAT' ) '(' propertyName ')' ) 'GROUP BY'?

linkedEntities
         ::= '{' linkEntity ( ',' linkEntity )* '}'

linkEntity
         ::= entityName '(' 'property' ( ',' 'property' )* ')' 'FROM' propertyName 'TO' propertyName ( 'LINK TYPE' ( 'LEFT' | 'RIGHT' | 'INNER' ) )? linkedEntities* ( 'FILTER' filter )? orderBy?

filter   ::= ( 'AND' | 'OR' ) '(' ( condition | filter ( ',' ( condition | filter )* )? )? ')'

condition
         ::= propertyName ( operator value | 'IS NULL' | 'IS NOT NULL' | 'IN' '(' value ( ',' value )* ')' | ( 'BEFORE NEXT' | 'AFTER NEXT' | 'IN NEXT' | 'BEFORE LAST' | 'AFTER LAST'
                  | 'IN LAST' ) value 'DAYS' )

operator ::= '=='
           | 'LIKE'
           | '>'
           | '<'
           | '>='
           | '<='
           | 'MATCH'

value    ::= string
           | int
           | decimal

orderBy  ::= 'ORDER BY' propertyName ( 'ASC' | 'DESC' ) ( ',' propertyName ( 'ASC' | 'DESC' ) )*

alias    ::= [A-Za-z_] [A-Za-z_0-9]*

entityName
         ::= [A-Za-z] [A-Za-z_0-9]*

propertyName
         ::= [A-Za-z] [A-Za-z_0-9]*

int      ::= [0-9]*

decimal  ::= [0-9]+ '.' [0-9]+

comment  ::= '/*' ( [^*] | '*'+ [^*/] )* '*'* '*/'

string   ::= '"' [^"]* '"'